IrfanView

Inhaltsverzeichnis

1 Beschreibung
2 CLI
3 Screenshots
4 Siehe auch
5 Weblinks
6 Kommentare

Beschreibung

Logo

IrfanView ist ein schneller und kostenloser Bildbetrachter für Windows. Er hat sich zu einem vielseitigen Werkzeug entwickelt, das nicht nur etwa 60 Bildformate, sondern auch wichtige Audio- und Video-Dateien (wie MP3, AVI, MPG, WAV, OGG) sowie animierte GIFs unterstützen kann.

Zusätzlich ermöglicht IrfanView das schnelle Durchblättern von Grafik-Sammlungen und das Anzeigen selbst ablaufender Diaschauen. Es bietet grundlegende Bildbearbeitungswerkzeuge, einen Grafik-Konverter und eine Scanner-Schnittstelle. Die Software wird nicht nur aufgrund ihres Freeware-Status geschätzt, sondern auch wegen ihrer umfassenden Funktionen. Die aktuelleren Versionen kommen mit zahlreichen neuen Funktionen und Bugfixes daher. Diese Freeware erfüllt alle wesentlichen Anforderungen eines Bildbetrachters.

Über das Menü Options -> Change Language kannst du die Sprachdatei auf Deutsch umstellen.

CLI

IrfanView bietet nicht nur eine grafische Oberfläche, sondern auch eine CLI (Command Line Interface), um automatisierte Skripte (Batch-Prozesse) auszuführen. So können beispielsweise alle Fotos in einem definierten Ordner automatisch verkleinert werden.

Das folgende Skript "thumbnail_QF.bat" verkleinert alle Querformat-Fotos im Ordner "D:\Ram\TechnikWiki\Upload" auf eine Größe von 2000x1500 Pixel und speichert sie im Ordner "D:\Ram\TechnikWiki\Upload\thumbnail" ab.

@echo off
rem Thumbnail creation with IrfanView
cls
setlocal
echo Create thumbnails
echo -----------------

rem ************
rem * Settings *
rem ************

rem Thumbnail width
set width=2000

rem File extension
set filetype=*.jpg

rem JPEG quality
set quality=50

rem Source path of the pictures
set source=D:\Ram\TechnikWiki\Upload

rem Prefix for thumbnails
set prefix=

rem Thumbnail sub directory name
set thumbnail=thumbnail

rem Silent mode?
rem Set silent to 0 means see all messages
rem Set silent to 1 means see just just the processed directories
rem Set silent to 2 means see no messages
set silent=0

rem Create thumbnails always
rem Set createallways to 0 if you like to create thumbnails for new files only
rem Set createallways to 1 to create new and overwrite existing thumbnails
set createallways=0

rem Resize what?
rem set resize=/resize=(%width%,%width%)
set resize=/resize_long=%width%
rem set resize=/resize_short=%width%

rem Path to Irfan view
set iview="D:\Ram\TechnikWiki\IrfanView\i_view64.exe"

if not exist %iview% goto noIview

rem *******************
rem * Script function *
rem *******************
rem Check source path
if not exist "%source%\." goto nosource

rem Process the source directory
for /f "delims=" %%a in ('pushd "%source%"^&cd^&popd') do call :createthb "%%~na" "%%a"

rem Get directory structure and call the routine for converting
for /f "delims=" %%a in ('dir /s /b /ad "%source%"') do call :createthb "%%~na" "%%a"

echo Finished.
goto end

rem Create the thumbnails
:createthb
rem First check if we are not in a thumbnail directory
if /i "%~1" equ "thumbnail" goto :eof

rem Check if the thumbnail subdirectory exists
if not exist "%~2\thumbnail" md "%~2\thumbnail"

rem Create thumbnails
if "%silent%" leq "1" echo Processing "%~2"...
for /f "delims=" %%b in ('dir /b /a-d "%~2\%filetype%"') do call :createthb2 "%~2" "%%~b"
goto :eof

rem Create thumbnail if it does not exist
:createthb2
rem if thumbnail exist => skip
if exist "%~1\%thumbnail%\%prefix%%~2" (
 if "%silent%" equ "0" echo Thumbnail "%~1\%thumbnail%\%prefix%%~2" for "%~1\%~2" found.
 if "%createallways%" equ "0" goto :eof
)

rem Create thumbnail
if "%silent%" equ "0" echo Creating thumbnail for "%~1\%~2".
start "IrfanView" /wait %iview% "%~1\%~2" /resize=(%width%,%width%) /aspectratio /resample /jpgq=%quality% /convert="%~1\%thumbnail%\%prefix%$F"
goto :eof

rem IrfanView could not be found.
:noiview
echo IrfanView not found in the given path:
echo   %iview%
goto end

rem Source path does not exist
:nosource
echo Source path
echo   %source%
echo not found. Please check the path.
goto end

rem End of the script
:end
pause
endlocal